Corel Draw export to LightBurn
1. Open the Macro Manager


2. Create a new module in the GlobalMacros project

3. Name the new module lightburn and right click and select edit. 

4. Copy the following into the open page

Sub Lightburn()
    Dim answer As Integer
    Dim OrigSelection As ShapeRange
    Set OrigSelection = ActiveSelectionRange
    OrigSelection.CreateSelection
    Dim expopt As StructExportOptions
    Set expopt = CreateStructExportOptions
    expopt.UseColorProfile = True
    Dim expflt As ExportFilter
    
    Dim out_file As String
    out_file = "C:" & Environ("HOMEPATH") & "\export.ai"
    If Len(Dir$(out_file)) > 0 Then
        Kill (out_file)
    End If
    
    ' is an item selected?
    If ActiveSelectionRange.Count > 0 Then
        ' something is selected export it
        Set expflt = ActiveDocument.ExportEx(out_file, cdrAI, cdrSelection, expopt)
        With expflt
            .Version = 2 ' FilterAILib.aiVersionCS2
            .TextAsCurves = True
            .PreserveTransparency = True
            .ConvertSpotColors = True
            .SimulateOutlines = False
            .SimulateFills = False
            .IncludePlacedImages = True
            .IncludePreview = True
            .EmbedColorProfile = True
            .Finish
        End With
        
    Else
        answer = MsgBox("Nothing was selected, Export All?", vbYesNo + vbQuestion, "Export All")
        If answer = vbYes Then
            ' Export everything
            Set expflt = ActiveDocument.ExportEx(out_file, cdrAI, cdrAllPages, expopt)
            With expflt
                .Version = 2 ' FilterAILib.aiVersionCS2
                .TextAsCurves = True
                .PreserveTransparency = True
                .ConvertSpotColors = False
                .SimulateOutlines = False
                .SimulateFills = False
                .IncludePlacedImages = True
                .IncludePreview = True
                .EmbedColorProfile = True
                .Finish
            End With
            
        Else
            'do nothing
            Exit Sub
        End If
    End If
    
    ' Edit this like if lightburn is in a diffrent location
    Call Shell("C:\Program Files\LightBurn\LightBurn.exe " & out_file, vbNormalFocus)
End Sub

It should look like this.

5. Close the macro editor
6. Now we need to add the button to the toolbar. Open the options menu. 
7. Select commands under the customization section and make sure the macro option is selected in the drop-down. Then drag the lightburn.lightburn macro to the toolbar.
7.1.  Optional: Change Icon.
Select the Appearance tab and select the lightburn macro. download logo.ico from the files section in the facebook group. Click the browse buttion and select logo.ico. you can also set a caption which will change lightburn.lightburn to anything you want. 


8. Now select the objects you want and click the button and Lightburn will be opened and the objects will be auto-imported. 





' LightBurn CorelDraw exporter / launcher
' Thanks to Casey Gadd for the original version

Sub Lightburn()
    Dim answer As Integer
    Dim OrigSelection As ShapeRange
    Set OrigSelection = ActiveSelectionRange
    OrigSelection.CreateSelection
    Dim expopt As StructExportOptions
    Set expopt = CreateStructExportOptions
    expopt.UseColorProfile = True
    Dim expflt As ExportFilter
    
    Dim outputFile As String
    outputFile = "C:" & Environ("HOMEPATH") & "\LBExport.ai"
    If Len(Dir$(outputFile)) > 0 Then
        Kill (outputFile)
    End If

    'Is anything selected?
    answer = vbYes  ' Assume success

    If ActiveSelectionRange.Count = 0 Then
        'Export everything if there's no selection
        Set expflt = ActiveDocument.ExportEx(outputFile, cdrAI, cdrAllPages, expopt)
    Else
        Set expflt = ActiveDocument.ExportEx(outputFile, cdrAI, cdrSelection, expopt)
    End If

    If answer = vbYes Then
        With expflt
            .Version = 2 ' FilterAILib.aiVersionCS2
            .TextAsCurves = True
            .PreserveTransparency = True
            .ConvertSpotColors = False
            .SimulateOutlines = False
            .SimulateFills = False
            .IncludePlacedImages = True
            .IncludePreview = True
            .EmbedColorProfile = False
            .Finish
        End With

        Call Shell("C:\Program Files\LightBurn\SendUDP.exe " & """" & outputFile & """", vbHide)
    End If
End Sub